Create MathScript

Download PDF

Updated2024-09-12
3 minute(s) read

Create MathScript

Use MathScripts to integrate MathScript functions from LabVIEW into DIAdem ANALYSIS. To execute MathScripts, you must have LabVIEW Version 8.0 or a later version, with the MathScript option, installed on your computer.

From DIAdem 2015, MathScript is no longer available in the DIAdem ANALYSIS menu. In order to create the menu item MathScript and the submenus Run and Edit in DIAdem ANALYSIS which the MathScript file Calculate3DSpiral uses in the CommonDocumentsPath folder, execute the following script in DIAdem SCRIPT.

VBScript

Python

Copy script

Dim ProjectPath: ProjectPath = CommonDocumentsPath & "Documents\"
const ProjectFile = "Calculate3DSpiral"    ' MSC file name without filename extension
const ProjectName = "MyProject"
'-------------------------------------------------------------------------------
function CreateMathScriptMenu(sgID, sgCaption, oParentBar)
  ' Create ActionObject for menu bar
  dim oActObj  
  if (BarManager.ActionObjs.Exists(sgID)) then
    set oActObj = BarManager.ActionObjs(sgID)
  else
    set oActObj = BarManager.ActionObjs.Add(sgID, "CustomPopup")
    oActObj.BarID = sgID
    oActObj.Caption = sgCaption
  end if
  if not (oParentBar.UsedActionObjs.Exists(sgID)) then
    call oParentBar.UsedActionObjs.Add(sgID)
  end if
  
  ' Create menu bar
  dim oBar
  if (BarManager.Bars.Exists(sgID)) then
    set oBar = BarManager.Bars(sgID)
  else
    set oBar = BarManager.Bars.Add(sgID)
    oBar.Style = eBarStyleIconCaption
    oBar.ActionObjPictureWidth = 16
    oBar.ActionObjPictureHeight = 16
  end if
  
  set CreateMathScriptMenu = oBar
end function

'-------------------------------------------------------------------------------
function CreateProjectMenuItem(sgID, sgCaption, oBar) 
  dim oActObj
  if (BarManager.ActionObjs.Exists(sgID)) then
    set oActObj = BarManager.ActionObjs(sgID)
  else
    set oActObj = BarManager.ActionObjs.Add(sgID, "CustomButton")
    oActObj.Caption = sgCaption
  end if
  if (not oBar.UsedActionObjs.Exists(oActObj)) then
    call oBar.UsedActionObjs.Add(oActObj)
  end if
  set CreateProjectMenuItem = oActObj
end function

'-------------------------------------------------------------------------------
' Main
'-------------------------------------------------------------------------------

dim oMenuItem, oMathScriptBar, oProjectBar

' Create MathScript menu bar
set oMathScriptBar = CreateMathScriptMenu("MyMathScriptMenu", "MathScript", BarManager.Bars("ANAMenuMain"))

' Create menu bar for MathScript Project1
set oProjectBar = CreateMathScriptMenu("MyMathScriptProject1Menu", ProjectName, oMathScriptBar)

' Create menu item "Run" for MathScript Project1
set oMenuItem = CreateProjectMenuItem(ProjectName & "Run", "Run", oProjectBar)
oMenuItem.OnClickCode.Code = "call GetMathScript.RunMathScript(""" & ProjectPath & """,""" & ProjectFile & """)"
' Create menu item "Edit" for MathScript Project1
set oMenuItem = CreateProjectMenuItem(ProjectName & "Edit", "Edit", oProjectBar)
oMenuItem.OnClickCode.Code = "call GetMathScript.EditMathScript(""" & ProjectPath & """,""" & ProjectFile & """)"

ProjectPath = dd.CommonDocumentsPath + "Documents\" 
ProjectFile = "Calculate3DSpiral" # MSC file name without filename extension
ProjectName = "MyProject" 
#-------------------------------------------------------------------------------
def CreateMathScriptMenu(sgID, sgCaption, oParentBar): 
# Create ActionObject for menu bar
    if (dd.BarManager.ActionObjs.Exists(sgID)) : 
        oActObj = dd.BarManager.ActionObjs(sgID) 
    else: 
        oActObj = dd.BarManager.ActionObjs.Add(sgID, "CustomPopup") 
        oActObj.BarID = sgID 
        oActObj.Caption = sgCaption 
    if not (oParentBar.UsedActionObjs.Exists(sgID)) : 
        oParentBar.UsedActionObjs.Add(sgID) 
# Create menu bar
    if (dd.BarManager.Bars.Exists(sgID)) : 
        oBar = dd.BarManager.Bars(sgID) 
    else: 
        oBar = dd.BarManager.Bars.Add(sgID) 
        oBar.Style = dd.eBarStyleIconCaption 
        oBar.ActionObjPictureWidth = 16 
        oBar.ActionObjPictureHeight = 16 
    CreateMathScriptMenu = oBar 
    return CreateMathScriptMenu
#-------------------------------------------------------------------------------
def CreateProjectMenuItem(sgID, sgCaption, oBar): 
    if (dd.BarManager.ActionObjs.Exists(sgID)) : 
        oActObj = dd.BarManager.ActionObjs(sgID) 
    else: 
        oActObj = dd.BarManager.ActionObjs.Add(sgID, "CustomButton") 
        oActObj.Caption = sgCaption 
    if (not oBar.UsedActionObjs.Exists(oActObj)) : 
        oBar.UsedActionObjs.Add(oActObj) 
    CreateProjectMenuItem = oActObj 
    return CreateProjectMenuItem
#-------------------------------------------------------------------------------
# Main
#-------------------------------------------------------------------------------
# Create MathScript menu bar
oMathScriptBar = CreateMathScriptMenu("MyMathScriptMenu", "MathScript", dd.BarManager.Bars("ANAMenuMain")) 
# Create menu bar for MathScript Project1
oProjectBar = CreateMathScriptMenu("MyMathScriptProject1Menu", ProjectName, oMathScriptBar) 
# Create menu item "Run" for MathScript Project1
oMenuItem = CreateProjectMenuItem(ProjectName + "Run", "Run", oProjectBar) 
oMenuItem.OnClickCode.Code = "call GetMathScript.RunMathScript(""" + ProjectPath + """,""" + ProjectFile + """)" 
# Create menu item "Edit" for MathScript Project1
oMenuItem = CreateProjectMenuItem(ProjectName + "Edit", "Edit", oProjectBar) 
oMenuItem.OnClickCode.Code = "call GetMathScript.EditMathScript(""" + ProjectPath + """,""" + ProjectFile + """)"

Further Settings

Create MathScript Menu | Define MathScript | Execute MathScript

In This Section

Further Settings

Was this information helpful?

Yes No

DIAdem Help

Filters

Content Type

Programming Language

Table of Contents

Create MathScript

Further Settings

In This Section

Additional Comments

Download PDF